V minulém povídání jsem ukázal, jak relativně jednoduše přenést požadavky z Excelu do Enterprise Architectu. Dnes předvedu, jak toho lze dosáhnout z Wordu. Mnohé společnosti totiž své požadavky píší právě v něm.

Postup tentokrát bude trochu složitější, ale většinu jsem pro vás připravil. Jak tedy na to? Především se podívejme na to, jak se požadavky ve Wordu zaznamenávají. Já jsem vycházel z jednoduché tabulky (ne, nebudu zapírat, že v praxi „mí“ zadavatelé používají právě ji) ve Wordu, kde první sloupec je identifikace (jedinečný název) požadavku, text požadavku, priorita a vlastník. Identifikace je povinná, ostatní je volitelné (soubor si můžete stáhnout):

Uvedená tabulka musí splňovat ještě některé další podmínky:

• Žádný řádek ve sloupcích nesmí začínat rovnítkem (níže řeknu proč).
• Text v tabulce nesmí být formátovaný (pokud přesto je, je toto formátování při převodu ignorováno).
• V tabulce nesmí být použity obrázky, vložené dokumenty a další netextové prvky (nebudou přeneseny).

Všimněte si také, že identifikace začíná zkratkou BR (Business Requirement) a dále číslem. Jednoduše v nich poznáte hierarchickou strukturu. Důležité je oddělovat jednotlivé úrovně tečkou, přičemž tyto úrovně musí být uvedeny na konci celé identifikace požadavku. Na začátku může být cokoliv. Tedy např. BR_1 a pak BR_1.1, nebo místo podtržítka mezera, místo BR slovo Požadavek nebo to může být úplně bez textu, jen s čísly. Ve Wordu lze navíc použít automatické číslování.

Vlastní převod bude probíhat s mezikrokem, který už dobře známe. Ano, přeneseme požadavky do Excelu. Ve Wordu označte celou tabulku (najeďte na ni myší, v levém horním rohu tabulky se objeví křížové šipky, na ně klikněte). Zkopírujte celou tabulku do schránky (pravé tlačítko myši nad křížovými šipkami a v kontextovém menu zvolit Kopírovat/Copy).

Nyní je třeba otevřít si Excel, ale pozor, nepůjde o libovolný sešit, ale je třeba si stáhnout speciální soubor s makrem (hned se k němu dostaneme), takže při otvírání je třeba makra povolit. Na záložce BR z Wordu pak označte pole A1 a vložte tabulku z Wordu. Výsledek bude vypadat přibližně takto:

Všimněte si jedné věci: u požadavku BR 1.3 jsem porušil pravidlo zákazu formátování textu. Tím jsem dostal nepříjemné rozdělení, ale zrovna s tímhle se skript popere se ctí.

V Excelu ze záložky View zvolte Macros a spusťte makro nazvané SpojPožadavky (jiné tam v seznamu stejně není).

Nyní se přepněte na záložku Požadavky pro EA. Uvidíte známou strukturu požadavků, jak jsme si ji ukazovali v předchozím článku.

Nyní tedy již zbývá jen uložit tento list jako CSV soubor a importovat do Enterprise Architectu. Definice importu je zřejmá:

Po importu se v Project Browseru objeví následující struktura:

Je vidět, že tentokráte nejsou použity balíky (Packages), ale vnořuji požadavky přímo do sebe (což ale lze ovlivnit úpravou makra).

Proč je to celé složitější a jak to funguje?

Postup je složitější z prostého důvodu: Enterprise Architect neumí přímý import z wordového dokumentu (abych byl upřímný, šlo by to pomocí OLE Automation např. přímo z Wordu, ale do toho se pouštět nechci). Proto bylo nutné udělat tento mezikrok s Excelem, který navíc použijeme pro přeformátování tabulky, která je sice příjemná zadavatelům, ale pro nás není úplně dostačující.

Klíčovým prvkem je skript v Excelu, který vykoná dost práce. Nejprve si jej můžete prostudovat:

    'maximální počet řádků, které ve vstupním sheetu zpracuju
    Const aMaxLinesToProcess As Integer = 5000
    
    'Konstanty listu Vstup
    Const cVstupSheet As String = "BR z Wordu"
  
    'Konstanty listu Výstup
    Const cVystupSheet = "Požadavky pro EA"


    'Globální proměnné
    Dim lVystupRow As Integer
    Dim shtVstup  As Worksheet  'list, kde najdu vstupní BR
    Dim shtVystup As Worksheet  'list, kam davam naformatované BR

Sub ClearSheet(ws As Worksheet)
    'vyčistí prvních 30 sloupců kromě prvního řádku
    'asi existuje elegantnější řešení, ale nemá cenu se jím trápit
    
    Dim lindex As Integer
        
    For lindex = 1 To 30
        lchar = Chr(lindex + 64) 'převedu si na znak "A" a vyšší
        
        If ws.Cells(ws.Rows.Count, lindex).End(xlUp).Row > 1 Then
            ws.Range(lchar & "2", ws.Cells(ws.Rows.Count, lindex).End(xlUp)).Clear
        End If
    
    Next lindex
End Sub

Sub WriteRequirement(aBR As String, aNotes As String, aPriority As String, aAuthor As String, aCSVKey As String, aCSVParentKey As String)
'zapíše jeden požadavek dle znění daného parametry na řádek dle globální proměné lVystupRow, kterou následně ještě navýší
    shtVystup.Cells(lVystupRow, 1).Value = aBR
    shtVystup.Cells(lVystupRow, 2).Value = aNotes
    shtVystup.Cells(lVystupRow, 3).Value = aPriority
    shtVystup.Cells(lVystupRow, 4).Value = aAuthor
    shtVystup.Cells(lVystupRow, 5).Value = "Requirement"
    shtVystup.Cells(lVystupRow, 6).Value = aCSVKey
    shtVystup.Cells(lVystupRow, 7).Value = aCSVParentKey
    lVystupRow = lVystupRow + 1
End Sub

Sub AppendTextToPreviousRequirement(aText As String)
'přidá text požadavku k předchozímu
    If lVystupRow > 2 Then
        shtVystup.Cells(lVystupRow - 1, 2).Value = shtVystup.Cells(lVystupRow - 1, 2).Value & Chr(10) & aText
    End If
End Sub

Function GetCSVKey(aText As String) As String
'z textu udělá klíč pro označení daného BR tak, že ořeže bílé znaky na začátku a na konci řetězce
    Dim znak As String
    Dim ascc As Integer
    
    'nejprve na konci (prostě proto, že mám na výběr a tedy chci) - ve skutečnosti to můžeme považovat za optimalisaci
    znak = Right(aText, 1)
    While (znak = ".") Or (znak = " ") Or (znak = Chr(9)) Or (znak = Chr(7)) Or (znak = Chr(160))
        aText = Left(aText, Len(aText) - 1)
        znak = Right(aText, 1)
    Wend
    
    'a pak na začátku
    znak = Left(aText, 1)
    While (znak = ".") Or (znak = " ") Or (znak = Chr(9)) Or (znak = Chr(7)) Or (znak = Chr(160))
        aText = Right(aText, Len(aText) - 1)
        znak = Left(aText, 1)
    Wend
        
    GetCSVKey = aText
    Exit Function
End Function

Function GetCSVParentKey(aText As String) As String
'rodič je určen odebráním posledního místa s tečkou
    If aText = "" Then
        GetCSVParentKey = ""
        Exit Function
    End If

    Dim lPointPos As Integer
    lPointPos = InStrRev(aText, ".")
    If lPointPos > 0 Then
        GetCSVParentKey = Mid(aText, 1, lPointPos - 1)
    Else
        GetCSVParentKey = ""
    End If

End Function


Sub SpojPožadavky()
    ' projedu celej sheet a pokud v prvním sloupci nic není, pak obsah toho druhého vložím k předchozímu, zbytek ignoruju.
    
    'nastavím proměnné pro listy
    Set shtVstup = Worksheets(cVstupSheet)
    Set shtVystup = Worksheets(cVystupSheet)
    
    ClearSheet shtVystup

    lVystupRow = 2

    Dim lVstupRow As Integer
    Dim lCSVKey As String
  
    For lVstupRow = 2 To aMaxLinesToProcess
        If shtVstup.Cells(lVstupRow, 1) = "" Then
            If shtVstup.Cells(lVstupRow, 2) <> "" Then
                AppendTextToPreviousRequirement shtVstup.Cells(lVstupRow, 2)
            End If
        Else
            lCSVKey = GetCSVKey(Trim(shtVstup.Cells(lVstupRow, 1)))
            WriteRequirement lCSVKey, shtVstup.Cells(lVstupRow, 2), shtVstup.Cells(lVstupRow, 3), shtVstup.Cells(lVstupRow, 4), lCSVKey, GetCSVParentKey(lCSVKey)
        End If
    Next lVstupRow

End Sub

Co vlastně dělá? Jeho úkolem je projít zdrojový list s požadavky překopírovanými z Wordu a připravit je pro export do CSV souboru. V případě, že narazí na řádek, který nemá zadanou identifikaci požadavku, ale má jeho text, přidá jej k tomu předchozímu. To nám vlastně vyřeší onen příklad s výčtem barev: sice se nepřenese formát výčtu, ale odrážky nám to alespoň provizorně zachová a přechod na nový řádek také, byť jde stále o jeden požadavek. Dále se snaží z identifikace požadavku vyčíst hierarchii a tu ve výsledku zohlednit.

Z uvedeného také plyne ono omezení, že požadavek (resp. nový řádek požadavku) nesmí začínat rovnítkem, neboť Excel by to pochopil jako vzorec (pokud ale chcete, můžete si skript zdokonalit).

Připouštím, že skript obsahuje pár nevzdělaných míst (např. mazání výsledkového listu nebo to, že standardně pracuje s prvními 5000 řádky zdrojového listu). Je jen na vás, abyste si jej případně upravili. Stejně tak můžete vložit vytváření balíků namísto vnořování požadavků nebo jinak pojmenovávat požadavky. Vše je na vaší vůli. Pokud se budete chtít podělit s vaším výsledkem, klidně to v komentáři udělejte.

Ne každý zaměstnanec v rámci jedné společnosti používá tytéž nástroje. Management či zadavatelé si často vystačí s aplikacemi ze sady Microsoft Office. Jenže lidé na IT si nechtějí nechat vzít své hračky a tak se snaží vstupy od zadavatelů přesýpat do jiných aplikací. Enterprise Architect tomu dokáže výrazně pomoci.

Zůstaňme však stále ve směru z aplikací Microsoft Office do Enterprise Architecta. Existují sice lepší cesty přes formát XMI, ale tím se (prozatím) zabývat nebudeme, neboť běžný uživatel toto nedokáže. Naší klíčovou aplikací dnes bude Excel.

V Excelu lze tvořit mnoho pěkných věcí, ale přiznejme si, že např. na správu požadavků to není úplně ideální nástroj (byť se někde používá). Nebude tedy od věci podívat se, jak právě požadavky z Excelu přenést do „éáčka“. Vezměme si jako příklad požadavky na nové auto. Každé oddělení má trochu jinou představu o tom, které parametry má nový vůz obsahovat, ale to není v tuto chvíli náš boj. Vše může vypadat např. takto:

Lze vidět, že máme požadavky rozdělené dle oddělení (zde manžel, manželka, dcera a syn), přičemž v oddělení syn máme dva zaměstnance (Tomáše a Jakuba). Každý ze zaměstnanců má své požadavky.

Co s tím? Abychom mohli požadavky do EA přenést, musíme nejprve s textem ještě něco málo udělat. Přidejte si proto poslední sloupec, nazvěte jej např. Typ a na každý řádek dejte hodnotu Requirement (vysvětlím záhy). Soubor si můžete i stáhnout. Nyní si uložte (nebo stáhněte) celou tabulku ve formátu CSV a přepněme se do Enterprise Architecta. Tam si v Project Browseru vytvořte balík, do kterého chcete požadavky importovat a přes pravé tlačítko zvolte Import/Export ► CSV Import/Export… Zobrazí se dialog podobný tomuto:

První krok, který uděláme (a jen jednou, netřeba jej opakovat při každém dalším importu souboru s touže strukturou), je vytvoření si definice našeho importu. Tím nástroji řekneme, co má v souboru hledat. Stiskněte tedy tlačítko Edit/New… a zobrazí se dialog pro definici importu:

Postupujte podle těchto kroků:

1. Zadejte název vaší definice.
2. Zvolte oddělovat záznamů v souboru.
3. Můžete vložit poznámku k vaší definici a stejně tak výchozí soubor, který se pokaždé bude nabízet (a bude možné změnit).
4. Výchozí směr (rozbalovací seznam Default Direction) bude Import.
5. Pole Default Types nechte prázdný (Název pole je zavádějící, ve skutečnosti se sem zadávají typy, které se mají importovat, ostatní se ignorují. Pokud je prázdné, pracuje se se všemi typy.).
6. Zaškrtávací políčko Preserve Hierarchy nechte nezaškrtnuté (ještě se k němu vrátím).
7. A nyní se dostaneme k tomu, že nadefinujeme význam všech sloupců, které v souboru máme. Postupně zadejte tato pole:
1. Name
2. Author
3. Priority
4. Notes
5. Type
8. Stiskněte Save a následně Close, čímž se vrátíte do předchozího dialogu.

Tady již zvolte vaši definici importu a uvidíte, že se jednotlivá pole nastaví dle toho, co jste zadali. Zbývá stisknout tlačítko Run a chvíli nedýchat. Pokud jste vše provedli správně, do vašeho balíku se dostaly všechny vaše požadavky. Uzavřete dialog stiskem tlačítka Close a podívejte se do Project Browseru, co se nám tam objevilo. Uvidíte tam několik požadavků s názvem „Dcera“, „Syn“ atd:

Není to moc přehledné, co říkáte? Ještě, než se pustíme do úpravy, otevřete si libovolný požadavek. Dostanete dialog podobný tomuto:

Pokud se podíváte pořádně, pak zjistíte, že se nám přenesl název požadavku, jeho autor a popis, ale chybí nám priorita. To by nás asi doma nepochválili.

Nejprve vyřešíme prioritu. Ta je definována seznamem hodnot, který můžeme libovolně měnit anebo mu přizpůsobit náš soubor exportovaný z Excelu. Pokud zvolíme tu první možnost, pak se podívejte do menu Settings ►Project Types ►General Types… a přepněte se na záložku Priority. Zde si můžete se seznamem pohrát tak, jak potřebujete. Jestliže volíte druhou možnost, pak se na uvedený dialog podívejte také, ať víte, z čeho můžete vybírat.

Nyní k našemu souboru v Excelu. První věc, která nás může dráždit, je název požadavku, který se opakuje. To není dobré. Zde doporučuji přesvědčit zadavatele, ať si svůj požadavek pojmenují. Buď nějak rozumně, nebo třeba číslem. Přidáme tedy do Excelu sloupeček pro název požadavku.

Druhá věc není na první pohled zřejmá. Pokud budou mít (a že budou) manželka s dětmi požadavků hodně, pak se v nich budete hůře orientovat. Zkusme si tedy udělat jednoduchou hierarchickou strukturu a rozdělit si požadavky do balíků podle jednotlivých členů rodiny.

Hierarchická struktura v souboru pro Enterprise Architect se dělá tak, že poslední dva sloupce se jmenují CSV_KEY a CSV_PARENT_KEY. V tom prvním je jedinečný klíč, který určuje daný řádek. V tom druhém je pak odkaz na rodiče. Předchozí příklad je rozšířen na následujícím obrázku (můžete si taktéž stáhnout xlsx i csv soubor). Jednotlivým členům rodiny necháme vytvořit balík a relevantní požadavky se pak na něj odkazují, čímž říkáme, že do nich patří.

Na základě této změny pak musíme samozřejmě upravit i definici importu: důležité je zaškrtnout políčko Preserve Hierarachy a upravit položky, které importujeme. Pokud vše nastavíte správně, můžete dostat v Project Browseru balíky podobné těmto:

Uznejte sami, že to už je mnohem příjemnější, než náš první výsledek.

Jak to funguje v praxi? Samozřejmě ne tak ideálně jako v tomto modelovém příkladě. Od zadavatele těžko můžeme chtít zadávat věci jako typ elementu k importu nebo hierarchickou strukturu. Jednou z možností je udělat si nějaké vzorečky a překlápět si požadavky na zvláštní list v excelovém souboru. Druhou je nechat zadavatele využít dobrodiní Wordu a nechat je psát požadavky v něm. Překlopení do Enterprise Architecta už je trochu složitější, ale i tak to jde. Ukážu to příště.

Poznámka 1: Popsané importování lze použít pro základní elementy, ne však např. pro jejich atributy. Pro to slouží již v úvodu zmíněný formát XMI.

Poznámka 2: Pro ukázky byl použit Enterprise Architect verze 9.3.933.